# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="A GTK-based image browser (with LIRC support)"
HOMEPAGE="http://gqview.sourceforge.net/"
SRC_URI="mirror://sourceforge/gqview/${P}.tar.gz
	http://www.tautologica.org/beniamino/download/patch-gqview-${PV}-lirc.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="lcms lirc"

RDEPEND=">=x11-libs/gtk+-2.4.0
	lcms? ( media-libs/lcms )
	virtual/libintl
	lirc? ( app-misc/lirc )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

src_unpack() {
	unpack ${A}
	cd "${S}"

	use lirc && epatch "${WORKDIR}/patch-gqview-${PV}-lirc"
}

src_compile() {
	econf \
		--disable-dependency-tracking \
		$(use_with lcms) \
		|| die
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	# leave README uncompressed because the program reads it
	dodoc AUTHORS ChangeLog TODO
	rm -f "${D}/usr/share/doc/${PF}/COPYING"
}